Uebungen  Exercices

4. Graphiken
 Graphiques

Die Gliederung dieses Kurses folgt in groben Zügen dem Buch von Nancy Blachman: A Practical Approach.... 
Hinweis: Kapitel 4 lesen!
Run mit WIN+Mathematica Version 5.2

 L'articulation de ce cours correspond à peu près à celle du livre de Nancy Blachman: A Practical Approach.... 
Indication: Lire le chapitre 4.
Testé avec Mathematica version 5.2+WIN

WIR94/98/99/2000/2007 // Copyright Rolf Wirz

Aufgabe 1    Problème 1

Spiele ein wenig mit den Options 
 Joue un peu avec les options

Sinus ohne ";"
  Sinus sans ";"

Plot[Sin[x],{x,0,6 Pi},
	AspectRatio -> 1/2,
	PlotLabel -> "Sin[x]",
	AxesLabel -> {"x", "y"},
	AxesOrigin -> {2 Pi, 1/2} ]

Sinus mit ";" --- Unterschied?
  Sinus avec ";" --- y a-t-il une différence?

Plot[Sin[x],{x,0,6 Pi},
	AspectRatio -> 1/2,
	PlotLabel -> "Sin[x]",
	AxesLabel -> {"x", "y"},
	AxesOrigin -> {2 Pi, 1/2} ];

Aufgabe 2    Problème 2

(a) Nullstellen schätzen
   Evaluer les zéros (estimer...)

Schätze die Nullstellen mit Hilfe des Plots:
  Evalue les zéros à l'aide de "Plots":

Plot[2x^3-7x^2-17x+10,{x,-6,6}];

Verifiziere die Schätzung mit "Solve":
Vérifier l'évaluation par "Solve":

Solve[2x^3-7x^2-17x+10==0,x]

(a) Nullstellen schätzen aus Graph:  
   Evaluer les zéros d'un graphe:

Schätze die Nullstellen mit Hilfe des Plots auf 3 Stellen (herauszoomen):
  Evalue les zéros à l'aide des "Plots" (3 places, zoom):

Plot[BesselJ[0,x],{x,-6,6}];

Verifiziere die Schätzung mit "Solve":
 Vérifie l'évaluation par "Solve":

Solve[2x^3-7x^2-17x+10==0,x]

Aufgabe 3    Problème 3

Verschiedene Dinge in einem Graphen:
 Plusieurs choses dans un graphe:

Zeichne den Graphen der Besselfunktion J0 sowie Liniensegmente, die vom Startpunkt der Newton-Iteration für die Nullstellen schliesslich zur Nullstelle führen:
  Dessine le graphe de la fonction d'après Bessel J0 ainsi que des segments de lignes, qui vont du point de départ de l'itération d'après Newton pour les zéros  au zéro:

Remove[t, x, y]

Show[
	Plot[BesselJ[0,x],{x,0,20},
		DisplayFunction -> Identity],
	Table[Graphics[{Dashing[{1/(10 t)}],
					Thickness[0.01],
					Evaluate[Line[{
						{t,BesselJ[0,t]},
						Evaluate[{y/. FindRoot[BesselJ[0,y]==0,
											{y,t}],0}]
						}]]
					}],
				{t,1,20,3}],
				DisplayFunction :> $DisplayFunction
				];

Aufgabe 4    Problème 4

(a) Plot einer Funktion und ihrer Potenzreihe:
   Plot d'une fonction et sa série de puissances:

f definieren:
  Définir f:

Clear[f]; f[x_]:=1/(1 + Sin[Sqrt[Pi^2 + x]^2]); f[x]

Verwende Series und Normal:  Achtung: Viel Output!
 Utilise "Series" et "Normal": Attention: Beaucoup d'Output!

n[x_]:=Normal[Series[f[x],{x,0,8}]]; 
nTest[x_]:=Normal[Series[f[x],{x,0,3}]]; 
nTest[x]

Plot von f und n:
  Plot de f et n:

Print[N[n[x]]]

a = 1;
Plot[Evaluate[N[n[x]]],Evaluate[{x,-a,a}],
				PlotStyle->{{Thickness[0.01],
		Dashing[{0.04}]}}];

a = 1; (*PlotRange*)
Show[
	Plot[f[x],Evaluate[{x,-a,a}],
		DisplayFunction -> Identity,
		PlotStyle->{GrayLevel[0.1]}],
	Plot[Evaluate[N[n[x]]],Evaluate[{x,-a,a}],
		DisplayFunction -> Identity,
		PlotStyle->{{Thickness[0.01],
		Dashing[{0.04}]}}],
		DisplayFunction :> $DisplayFunction];

Aufgabe 5    Problème 5

(a)  Probleme mit PlotPoints
    Problèmes avec Plotpoints

x^2+cos(22x) : 
Fehler beim Plotten bei normal vielen PlotPoints (in alten Versionen):
  Erreurs qui apparaissent en plotant avec un nombre normal de Plotpoints (vieilles vérsions):

Plot[x^2 + Cos[22x], {x,-5,5}];

Plot[x^2  +  Cos[22  x],  {x, -5, 5}, 
        PlotPoints -> 9];

(b)  Korrektur mit PlotPoints

x^2+cos(22x) : 
Wähle 70  PlotPoints:
  Choisir 70 "PlotPoints":

Plot[x^2  +  Cos[22  x],  {x, -5, 5}, 
        PlotPoints -> 70];

Aufgabe 6    Problème 6

Einige ParametricPlots: 
 Quelques "ParametricPlots":

(a)

ParametricPlot[{Cos[4t] Cos[t],Cos[4t] Sin[t]},{t,0,2 Pi},
AspectRatio->Automatic];

(b)

ParametricPlot[{Cos[7t] Cos[3t],Cos[7t] Sin[3t]},{t,0,2 Pi},
AspectRatio->Automatic];

(c)

ParametricPlot[{Cos[7t] Cos[11t],Cos[7t] Sin[11t]},{t,0,2 Pi},
AspectRatio->Automatic];

Aufgabe 7    Problème 7

Spiel mit dem Package "Polyhedra.m"
 Jeu avec le Package "Polyhedra.m"

Einbinden:    Lier:

Needs["Graphics`Polyhedra`"];

Graphik ansehen:
  Regarder le graphique:

Show[Graphics3D[Icosahedron[]]];

Graphik ansehen:
  Regarder le graphique:

Show[Graphics3D[Stellate[Icosahedron[],3]],
	Boxed->False];

Aufgabe 8    Problème 8

Lighting

Normal:    Normal:

Plot3D[Sin[x y],{x,-5,5},{y,-5,5}];

Lighting false:    Lighting false:

Plot3D[Sin[x y],{x,-5,5},{y,-5,5},Lighting->False];

Aufgabe 9    Problème 9

ViewPoint

Normal:    Normal:

Plot3D[Sin[x y],{x,-5,5},{y,-5,5},Lighting->True,
		ViewPoint->{0,0,3}];

Anders:    Autrement:

Plot3D[Sin[x y],{x,-5,5},{y,-5,5},Lighting->True,
		ViewPoint->{0,0,10}];

Nochmals anders: 
  Encore autrement:

Plot3D[Sin[x y],{x,-5,5},{y,-5,5},Lighting->True,
		ViewPoint->{0,3,10}];

Oder so:
  Ou ainsi:

Plot3D[Sin[x y],{x,-5,5},{y,-5,5},Lighting->True,
		ViewPoint->{2,-4,6}];

Aufgabe 10    Problème 10

Contour- und DensityPlot
 Contour- et DensityPlot

Contour:    Contour:

ContourPlot[Sin[x y],{x,-5,5},{y,-5,5}];

Density:    Density:

DensityPlot[Sin[x y],{x,-5,5},{y,-5,5}];

Aufgabe 11    Problème 11

Mit ContourPlot zu Ellipsen:
 Faire des ellipses avec ContourPlot

Contour:    Contour:

ContourPlot[x^2 + 2 y^2,{x,-5,5},{y,-5,5}, 
AspectRatio->Automatic];

Aufgabe 12    Problème 12

Spiel mit Listen:
 Jouer avec des listes

Primzahlen generieren:
  Générer des nombres premiers:

t = Table[Prime[n],{n,10}]

Plot:    Plot:

ListPlot[t,PlotStyle->{PointSize[0.05]}];

Punkte verbinden:
  Relier des points:

ListPlot[t,PlotStyle->{PointSize[0.05]},
		PlotJoined->True];

Fit:    Fit:

?Fit

tfit = Fit[t,{1,x,x^2},x]

Fit-Kurve ansehen:
Regarder la courbe Fit:

Plot[tfit,{x,0,30}];

Kurve zusammen mit Punkten ansehen:
  Regarder la courbe et les points ensemble:

Show[
	ListPlot[t,PlotStyle->{PointSize[0.05]},
		DisplayFunction -> Identity],
	Plot[tfit,{x,0,10},DisplayFunction -> Identity], DisplayFunction :> $DisplayFunction
			];

Abweichungen:    Ecarts:

t = Table[Prime[n],{n,10}];
rang=Range[Length[t]]

tNew=Transpose[{rang,t}]

Clear[tfit]; tfit[x_] := Fit[tNew,{1,x,x^2},x];

tfit[x]

tfit[x] /.x->3

te = Table[Prime[n]-(tfit[x]/.x->n),{n,10}]

Abweichungen im Plot:
  Ecarts dans le Plot:

Show[
	ListPlot[tNew,PlotStyle->{PointSize[0.05]},
		DisplayFunction -> Identity],
	ListPlot[te,PlotStyle->{PointSize[0.035]},
		DisplayFunction -> Identity],
	Plot[Evaluate[(tfit[x]/.x->n)],{n,0,10},DisplayFunction -> Identity],
    DisplayFunction :> $DisplayFunction
				];

Aufgabe 13    Problème 13

Zeichnen mit Mathematica 
 Dessiner avec Mathematica

Also los (Golden Gate Bridge):
  Allez-y (Golden Gate Bridge):

Show[
	Graphics[{ (*Brücke*)
		Circle[{-2,1},1,{3 Pi/2, 2 Pi}],
		Circle[{0,1},1,{Pi, 2 Pi}],
		Circle[{2,1},1,{Pi, 3 Pi/2}],
		Line[{{-2,0},{2,0}}],
		Line[{{-1,-0.5},{-1,1}}],
		Line[{{1,-0.5},{1,1}}]        }],
	Graphics[ (*Wasser*)
		Table[Circle[{x,-0.5},0.1,{Pi, 2Pi}],
			{x, -2, 2, 0.2}]         ],
	Graphics[{ (*Fisch*)
		Circle[{0,-1.2},0.4,{Pi/6, 5 Pi/6}],
		Circle[{0,-0.8},0.4,{7 Pi/6, 11 Pi/6}],
		Point[{-0.2,-0.95}],
		Circle[{-0.3,-1},0.2,{- Pi/4, Pi/4}],
		Line[{{0.35,-1},{0.5,-0.85},
			 {0.5,-1.15},{0.35,-1}}]
			 }],
		AspectRatio->Automatic,
		PlotRange->All  ];

Aufgabe 14    Problème 14

Zeichnen mit Mathematica 
 Dessiner avec Mathematica

Also los (geometrisches Gesicht):
  Allez-y (visage géométrique):

Show[
	Graphics[{ 
		(*Augen*)
		PointSize[0.04],
		Point[{-0.3,0.1}],
		Point[{0.3,0.1}],
		(*Nase*)
		Disk[{0,0},0.35,{23 Pi/16, 25 Pi/16}],
		(*Mund*)
		Line[{{-0.3,-0.5},{0,-0.6}}],
		Line[{{0,-0.6},{0.3,-0.5}}],
		(*Kopf*)
		Circle[{0,0},1]
		 }],
		AspectRatio->Automatic,
		PlotRange->All  ];

Aufgabe 15    Problème 15

Zeichnen mit Mathematica 
 Dessiner avec Mathematica

Wie wirken Farben?:
  Quels sont les effets des couleurs?

Show[
	Graphics[
		Table[{
			RGBColor[0,x/4.,1.-x/4.],
			Point[{x, Cos[x^2] - Sin[x]}]},
			{x,0,4,0.01}
			]
			],
			Axes->Automatic
		];

"Putzmaschine" einsetzen
 Employer la "machine de nettoyage"

(* Old Form: Remove["Global`@*"] *)

Remove["Global`*"]