Konzept und Darstellung der nachfolgenden Ergebnisse sind Resultate von durch Studenten ausgeführten Arbeiten - WIR

Krümmung und Anschmiegekreis bei räumlichen  Kurven

Kurven im (R^(2 ))

Krümmung und Anschmiegekreis bei ebenen  Kurven

Remove["Global`*"]

r[x0_]:=
(Abs[((D[f[x],x]^2+1)^(3/2))/D[f[x],{x,2}]]/.x->x0)

x0=1;
f[x_]:= E^x;
Evaluate[r[1]]

%//N

m[x0_]:= {x0,f[x0]}-{1,(-1/D[f[x],x]/.x->x0)}/Abs[Sqrt[{1,(-1/D[f[x],x]/.x->x0)}.{1,(-1/D[f[x],x]/.x->x0)}]] r[x0];
m[u]

m[x0_]:= Evaluate[{x0,f[x0]}-{1,(-1/D[f[x],x]/.x->x0)}/Abs[Sqrt[{1,(-1/D[f[x],x]/.x->x0)}.{1,(-1/D[f[x],x]/.x->x0)}]] r[x0]];
m[u]

p1=Plot[f[t],{t,-16,3},AspectRatio->Automatic,DisplayFunction->Identity];
p2=ParametricPlot[Evaluate[r[x0]]{Cos[t],Sin[t]}+m[x0],{t,0,2Pi},AspectRatio->Automatic,DisplayFunction->Identity];
Show[Graphics[{PointSize[0.05],Point[{x0,f[x0]}]}],p1,p2,DisplayFunction->$DisplayFunction,AspectRatio->Automatic];

Kurven im (R^(3 ))

Berechnung von Krümmung und Anschmiegekreis bei Raumkurven

Definition der Raumkurve

Remove["Global`*"]

x[t_] := 0.5 t Cos[t];   y[t_] :=  t Sin[t];   z[t_] := 
      t;    v[t_] := {x[t], y[t], z[t]};

Definition des Bereiches der Variablen

tmin = 0.1;   tmax =  10;

Plot Ausgangsfunktion

origPlot = 
        ParametricPlot3D[
          Evaluate[Join[v[t],  {RGBColor[1, 0, 0]}]], {t, tmin, tmax}, 
          PlotRange -> All, AxesLabel -> {x, y, z}, 
          AspectRatio -> Automatic];

Begleitendes Dreibein

vLen[v_] := Sqrt[v . v]; 
normVec[v_] := v/vLen[v];
tg[t_] = normVec[v'[t]];
n[t_] = 
        normVec[Cross[
            Cross[v'[t], v''[t]], v'[
              t]]];
b[t_] := Cross[tg[t], n [t]];

{tg[t], n[t], b[t]}

tVec[t_] := 
        Line[{v[t], v[t] + 3  tg[t]}];
nVec[t_] := 
        Line[{v[t], v[t] + 3  n[t]}];
bVec[t_] := Line[{v[t], v[t] + 3  b[t]}];

dreibein[t_] := 
      Graphics3D[{RGBColor[1, 0, 1], tVec[t], RGBColor[0.01, 0.6, 0.62], 
          nVec[t], RGBColor[0.54, 0.17, 0.89], bVec[t]}]

Show[origPlot, dreibein[5]];

Krümmung

ϰ[t_] = 
        Sqrt[(((v''[t] . v''[t])*(v'[t] . v'[
                          t]) - (v''[t] . v'[t])^2)/
              vLen[v'[t]]^6)];
ϰ[t]

Plot[Evaluate[ϰ[t]], {t, tmin, tmax}];

Krümmungsradius

ρ[t_] := Abs[1/ϰ[t]];   ρ[t]

Plot[Evaluate[ρ[t]], {t, tmin, tmax}];

Krümmungskreismittelpunkt (Evolute)

m[t_] := v[t] +  ρ[t]*n[t];   m[t]

evolute = 
        ParametricPlot3D[
          Evaluate[Join[m[t], {RGBColor[0, 0, 1]}]], {t, tmin, tmax}, 
          PlotRange -> All, AspectRatio -> Automatic];

Schmiegekreis

myCirc3d[t_, k_] :=  
      m[t] +  ρ[t] (n[t] Cos[k] + tg[t] Sin[k]);   myCirc3d[t, 
      k]

Plot

circPlot[t_] := 
        ParametricPlot3D[
          Evaluate[Join[myCirc3d[t, k], {RGBColor[0, 1, 0]}]], {k, 0, 2 Pi}, 
          DisplayFunction -> Identity];

Show[origPlot, circPlot[6]];

Alles zusammen

Show[origPlot, circPlot[6], dreibein[6]];

Animation

zentrum[t_] := 
      Graphics3D[{RGBColor[1, 0.8, 0], PointSize[0.02], Point[m[t]] }];  
    zentrum[t]

Do[Show[evolute, origPlot, circPlot[s], zentrum[s], dreibein[s], 
        DisplayFunction -> $DisplayFunction,  
        AspectRatio -> Automatic, 
        PlotRange -> {{-15, 15}, {-12, 12}, {-1, 12}}, 
        AxesLabel -> {x, y, z}], {s, tmin, tmax, 0.2}]